TIME
[
VLIB_TIME:z   {<choice $z>}
]

VLIB_TIME [

  ; Six o'clock
  ( VSUB_TIME_HOUR_NUMBERS:h ?o'clock ) {return([<time $h>])}

  ; Six o'clock in the morning
  ( VSUB_TIME_HOUR_NUMBERS:h ?o'clock VSUB_TIME_AM_PM:a 
  ) {return([<time $h> <am_pm $a>])}

  ; Twelve noon
  ( ?( twelve ?o'clock ) noon ) {return([<time 0> <am_pm "pm">])}  

  ; Twelve midnight
  ( ?( twelve ?o'clock ) midnight ) {return([<time 0> <am_pm "am">])}  

  ; Six fifteen
  ( VSUB_TIME_HOUR_NUMBERS:h VSUB_FOLLOWING_MINUTES:m 
  ) {return([<time add($h $m)>])}

  ; Seven thirty three a m
  ( VSUB_TIME_HOUR_NUMBERS:h VSUB_FOLLOWING_MINUTES:m VSUB_TIME_AM_PM:a 
  ) {return([<time add($h $m)> <am_pm $a>])}

  ; a quarter past six
  ( VSUB_HOUR_MODIFIER_POSITIVE:m VSUB_TIME_HOUR_NUMBERS_EXCEPT_TWELVE:h ?o'clock 
  ) {return([<time add($h $m)>])}

  ; a quarter to six
  ( VSUB_HOUR_MODIFIER_NEGATIVE:m VSUB_TIME_HOUR_NUMBERS_EXCEPT_TWELVE:h ?o'clock 
  ) {return([<time sub($h add(40 $m))>])}

  ; a quarter past six in the morning
  ( VSUB_HOUR_MODIFIER_POSITIVE:m VSUB_TIME_HOUR_NUMBERS_EXCEPT_TWELVE:h ?o'clock 
    VSUB_TIME_AM_PM:a
  ) {return([<time add($h $m)> <am_pm $a>])}

  ; a quarter to six p m
  ( VSUB_HOUR_MODIFIER_NEGATIVE:m VSUB_TIME_HOUR_NUMBERS_EXCEPT_TWELVE:h ?o'clock 
    VSUB_TIME_AM_PM:a
  ) {return([<time sub($h add(40 $m))> <am_pm $a>])}

    ; half past twelve
  ( VSUB_HOUR_MODIFIER_POSITIVE:m twelve ) {return([<time $m>])}

  ; ten minutes to twelve
  ( VSUB_HOUR_MODIFIER_NEGATIVE:m twelve ) {return([<time sub(1160 $m)>])}

  ; half past noon
  ( VSUB_HOUR_MODIFIER_POSITIVE:m ?twelve noon 
  ) {return([<time $m> <am_pm "pm">])}

  ; quarter to noon
  ( VSUB_HOUR_MODIFIER_NEGATIVE:m ?twelve noon 
  ) {return([<time sub(1160 $m)> <am_pm "am">])}
  
  ; half past midnight
  ( VSUB_HOUR_MODIFIER_POSITIVE:m ?twelve midnight 
  ) {return([<time $m> <am_pm "am">])}

  ; quarter to midnight
  ( VSUB_HOUR_MODIFIER_NEGATIVE:m ?twelve midnight
  ) {return([<time sub(1160 $m)> <am_pm "pm">])}
]

VSUB_TIME_HOUR_NUMBERS [
  VSUB_TIME_HOUR_NUMBERS_EXCEPT_TWELVE:n {return($n)}	     
  twelve {return(0)}
]

VSUB_TIME_HOUR_NUMBERS_EXCEPT_TWELVE [
  VSUB_DIGIT_ONE_THRU_NINE:n {return(mul($n 100))}
  ten {return(1000)}
  eleven {return(1100)}
]

VSUB_TIME_AM_PM [
  ( a m 
    ?VSUB_TIME_IN_THE_MORNING
  ) {return("am")}
  ( p m 
    ?VSUB_TIME_AT_NIGHT
  ) {return("pm")}
  VSUB_TIME_IN_THE_MORNING {return("am")}
  VSUB_TIME_AT_NIGHT {return("pm")}
]

VSUB_TIME_IN_THE_MORNING [
  ( in the morning ) 
  ( this morning )
]

VSUB_TIME_AT_NIGHT [
  ( at night ) 
  tonight
  ( [ ( in the ) this ] [ afternoon evening ] )
]

VSUB_HOUR_MODIFIER_POSITIVE [
  ( half past ) {return(30)}
  ( [ VSUB_DIGIT_ONE_THRU_NINE:m VSUB_MINUTES:m ] ?minutes [ past after ] 
  ) {return($m)}
  ( ?a quarter [ past after ] ) {return(15)}
]

VSUB_HOUR_MODIFIER_NEGATIVE [
  ( ?a quarter VSUB_TIL ) {return(15)}
  ( VSUB_DIGIT_ONE_THRU_NINE:n ?minutes VSUB_TIL ) {return($n)}
  ( ten ?minutes VSUB_TIL ) {return(10)}
  ( VSUB_TEEN:t ?minutes VSUB_TIL ) {return($t)}
  ( twenty ?minutes VSUB_TIL ) {return(20)}
]

VSUB_FOLLOWING_MINUTES [
  VSUB_MINUTES:m {return($m)}
  ( oh VSUB_DIGIT_ONE_THRU_NINE:m ) {return($m)}
]



VSUB_MINUTES [
  ten {return(10)}
  VSUB_TEEN:t {return($t)}
  VSUB_DECADE_TWENTY_THRU_FIFTY:t {return($t)}  
  ( VSUB_DECADE_TWENTY_THRU_FIFTY:t VSUB_DIGIT_ONE_THRU_NINE:m 
  ) {return(add($t $m))}
]

;;;;;;;;;;;;;

VSUB_DECADE_TWENTY_THRU_FIFTY [
  twenty {return(20)}
  thirty {return(30)}
  forty {return(40)}
  fifty {return(50)}
]

VSUB_TIL [
  til
  until
  to
  before
]

VSUB_DIGIT_ONE_THRU_NINE [
  one {return(1)}
  VSUB_DIGIT_TWO_THRU_NINE:n {return($n)}
]

VSUB_DIGIT_TWO_THRU_NINE [
  two {return(2)}
  three {return(3)}
  four {return(4)}
  five {return(5)}
  six {return(6)}
  seven {return(7)}
  eight {return(8)}
  nine {return(9)}
]



VSUB_DIGIT_TWO_THRU_NINE_STRING [
  two {return("2")}
  three {return("3")}
  four {return("4")}
  five {return("5")}
  six {return("6")}
  seven {return("7")}
  eight {return("8")}
  nine {return("9")}
]

VSUB_DIGIT_ONE_THRU_NINE_STRING [
  one {return("1")}
  VSUB_DIGIT_TWO_THRU_NINE_STRING:n {return($n)}
]

VSUB_DIGIT_STRING [
  [ zero oh ] {return("0")}
  VSUB_DIGIT_ONE_THRU_NINE_STRING:n {return($n)}
]

VSUB_TEEN_STRING [
  eleven {return("11")}
  twelve {return("12")}
  thirteen {return("13")}
  fourteen {return("14")}
  fifteen {return("15")}
  sixteen {return("16")}
  seventeen {return("17")}
  eighteen {return("18")}
  nineteen {return("19")}
]

VSUB_DECADE_STRING [
  twenty {return("2")}
  thirty {return("3")}
  forty {return("4")}
  fifty {return("5")}
  sixty {return("6")}
  seventy {return("7")}
  eighty {return("8")}
  ninety {return("9")}
]

VSUB_TEEN [
  eleven {return(11)}
  twelve {return(12)}
  thirteen {return(13)}
  fourteen {return(14)}
  fifteen {return(15)}
  sixteen {return(16)}
  seventeen {return(17)}
  eighteen {return(18)}
  nineteen {return(19)}
]

VSUB_DECADE [
  twenty {return(20)}
  thirty {return(30)}
  forty {return(40)}
  fifty {return(50)}
  sixty {return(60)}
  seventy {return(70)}
  eighty {return(80)}
  ninety {return(90)}
]