1_CHARACTER_ALPHA
[
VLIB_1_CHARACTER_ALPHA:z {<choice $z>}
]

; 1-character alpha string (~450 entries)
VLIB_1_CHARACTER_ALPHA ( 
  VSUB_ALPHA:a1 
) {return($a1)}


2_CHARACTER_ALPHA
[
VLIB_2_CHARACTER_ALPHA:z {<choice $z>}
]


; 2-character alpha string (~200k entries)
VLIB_2_CHARACTER_ALPHA ( 
  VSUB_ALPHA:a1 VSUB_ALPHA:a2 
) {return(strcat($a1 $a2))}


3_CHARACTER_ALPHA
[
VLIB_3_CHARACTER_ALPHA:z {<choice $z>}
]


; 3-character alpha string (~90 million entries)
VLIB_3_CHARACTER_ALPHA ( 
  VSUB_ALPHA:a1 VSUB_ALPHA:a2 VSUB_ALPHA:a3 
) {return(strcat(strcat($a1 $a2) $a3))}


4_CHARACTER_ALPHA
[
VLIB_4_CHARACTER_ALPHA:z {<choice $z>}
]


; 4-character alpha string  (~40 billion entries)
VLIB_4_CHARACTER_ALPHA ( 
  VSUB_ALPHA:a1 VSUB_ALPHA:a2 VSUB_ALPHA:a3 VSUB_ALPHA:a4 
) {return(strcat(strcat($a1 $a2) strcat($a3 $a4)))}

; If your code has any prohibited letters, it can help recognition
; accuracy to remove those letters from this grammar.
VSUB_ALPHA [
  VSUB_LETTER_A:a
  VSUB_LETTER_B:a
  VSUB_LETTER_C:a
  VSUB_LETTER_D:a
  VSUB_LETTER_E:a
  VSUB_LETTER_F:a
  VSUB_LETTER_G:a
  VSUB_LETTER_H:a
  VSUB_LETTER_I:a
  VSUB_LETTER_J:a
  VSUB_LETTER_K:a
  VSUB_LETTER_L:a
  VSUB_LETTER_M:a
  VSUB_LETTER_N:a
  VSUB_LETTER_O:a
  VSUB_LETTER_P:a
  VSUB_LETTER_Q:a
  VSUB_LETTER_R:a
  VSUB_LETTER_S:a
  VSUB_LETTER_T:a
  VSUB_LETTER_U:a
  VSUB_LETTER_V:a
  VSUB_LETTER_W:a
  VSUB_LETTER_X:a
  VSUB_LETTER_Y:a
  VSUB_LETTER_Z:a
] {return(strcat("" $a))}

; Grammars for indivividual letters with military alphabet equivalents.
;
; Allows "a", "alpha", "a as in alpha", etc.  "a alpha" is not allowed
; to prevent a potential ambiguity.  Strict military alphabet is always
; included (the first item on each list of words).  Common alternatives
; are also included, as seen in live system data.

VSUB_AS_IN [
   ( as in ) 
   ( as )
   ( like )
   ( like in )
   ( for )
]

VSUB_LETTER_A [ 
  a 
  ( ?( a VSUB_AS_IN ) [ alpha adam apple ] ) 
] {return("a")}

VSUB_LETTER_B [ 
  b 
  ( ?( b VSUB_AS_IN ) [ bravo baker boy bob ] ) 
] {return("b")}

VSUB_LETTER_C [ 
  c 
  ( ?( c VSUB_AS_IN ) [ charlie cat charles ] ) 
] {return("c")}

VSUB_LETTER_D [ 
  d 
  ( ?( d VSUB_AS_IN ) [ delta david dog ] ) 
] {return("d")}

VSUB_LETTER_E [ 
  e 
  ( ?( e VSUB_AS_IN ) [ echo edward edgar ] ) 
] {return("e")}

VSUB_LETTER_F [ 
  f 
  ( ?( f VSUB_AS_IN ) [ ( fox trot ) fox frank ] ) 
] {return("f")}

VSUB_LETTER_G [ 
  g 
  ( ?( g VSUB_AS_IN ) [ golf george girl ] ) 
] {return("g")}

VSUB_LETTER_H [ 
  h 
  ( ?( h VSUB_AS_IN ) [ hotel harry henry ] ) 
] {return("h")}

VSUB_LETTER_I [ 
  i 
  ( ?( i VSUB_AS_IN ) [ india ] ) 
] {return("i")}

VSUB_LETTER_J [ 
  j 
  ( ?( j VSUB_AS_IN ) [ juliet jack john ] ) 
] {return("j")}

VSUB_LETTER_K [ 
  k 
  ( ?( k VSUB_AS_IN ) [ kilo karen king ] ) 
] {return("k")}

VSUB_LETTER_L [ 
  l 
  ( ?( l VSUB_AS_IN ) [ lima larry linda lisa ] ) 
] {return("l")}

VSUB_LETTER_M [ 
  m 
  ( ?( m VSUB_AS_IN ) [ mike mary michael mother ] ) 
] {return("m") }

VSUB_LETTER_N [ 
  n 
  ( ?( n VSUB_AS_IN ) [ november nancy ] ) 
] {return("n")}

VSUB_LETTER_O [ 
  o 
  ( ?( o VSUB_AS_IN ) [ oscar ] ) 
] {return("o")}

VSUB_LETTER_P [ 
  p 
  ( ?( p VSUB_AS_IN ) [ papa paul peter ] ) 
] {return("p")}

VSUB_LETTER_Q [ 
  q 
  ( ?( q VSUB_AS_IN ) [ quebec ] ) 
] {return("q")}

VSUB_LETTER_R [ 
  r 
  ( ?( r VSUB_AS_IN ) [ romeo richard robert ] ) 
] {return("r")}

VSUB_LETTER_S [ 
  s 
  ( ?( s VSUB_AS_IN ) [ sierra sam ] ) 
] {return("s")}

VSUB_LETTER_T [ 
  t 
  ( ?( t VSUB_AS_IN ) [ tango tom thomas ] ) 
] {return("t")}

VSUB_LETTER_U [ 
  u 
  ( ?( u VSUB_AS_IN ) [ uniform uncle union ] ) 
] {return("u")}

VSUB_LETTER_V [ 
  v 
  ( ?( v VSUB_AS_IN ) [ victor victory ] ) 
] {return("v")}

VSUB_LETTER_W [ 
  w 
  ( ?( w VSUB_AS_IN ) [ whiskey walter william ] ) 
] {return("w")}

VSUB_LETTER_X [ 
  x 
  ( ?( x VSUB_AS_IN ) [ x-ray ] ) 
] {return("x")}

VSUB_LETTER_Y [ 
  y 
  ( ?( y VSUB_AS_IN ) [ yankee yellow ] ) 
] {return("y")}

VSUB_LETTER_Z [ 
  z 
  ( ?( z VSUB_AS_IN ) [ zulu ] ) 
] {return("z")}