YEAR_WITH_CENTURY
[
VLIB_YEAR_WITH_CENTURY:z {<choice $z>}
]

VLIB_YEAR_WITH_CENTURY [
	VSUB_YEAR_WITH_CENTURY:y
] { return (strcat ("" $y)) }

VSUB_YEAR_WITH_CENTURY [

  ; 1900
  ( nineteen hundred ) {return(1900)}

  ; 1901-1909
  ( nineteen [ ( hundred ?and ) oh ] VSUB_DIGIT_ONE_THRU_NINE:n ) {return(add(1900 $n))}

  ; 1910
  ( nineteen ?( hundred ?and ) ten ) {return(1910)}

  ; 1911-1919
  ( nineteen ?( hundred ?and ) VSUB_TEEN:t ) {return(add(1900 $t))}

  ; 1920-1990, even 10's only
  ( nineteen ?( hundred ?and ) VSUB_DECADE:t ) {return(add(1900 $t))}

  ; 1921-1999, except even 10's
  ( nineteen ?( hundred ?and ) VSUB_DECADE:t VSUB_DIGIT_ONE_THRU_NINE:u
  ) {return(add(1900 add($t $u)))}

  ; 2000
  ( ?( the year ) two thousand ) {return(2000)}

  ; 2001-2009
  ( [ ( twenty oh ) ( two thousand ?and ) ] VSUB_DIGIT_ONE_THRU_NINE:n 
  ) {return(add(2000 $n))}

  ; 2010
  ( [ twenty ( two thousand ?and ) ] ten ) {return(2010)}

  ; 2011-2019
  ( [ twenty ( two thousand ?and ) ] VSUB_TEEN:t ) {return(add(2000 $t))}

  ; 2020-2090, even 10's only
  ( [ twenty ( two thousand ?and ) ] VSUB_DECADE:t ) {return(add(2000 $t))}

  ; 2021-2099, except even 10's
  ( [ twenty ( two thousand ?and ) ] VSUB_DECADE:t VSUB_DIGIT_ONE_THRU_NINE:u
  ) {return(add(2000 add($t $u)))}
]



VSUB_DIGIT_TWO_THRU_NINE [
  two {return(2)}
  three {return(3)}
  four {return(4)}
  five {return(5)}
  six {return(6)}
  seven {return(7)}
  eight {return(8)}
  nine {return(9)}
]

VSUB_DIGIT_ONE_THRU_NINE [
  one {return(1)}
  VSUB_DIGIT_TWO_THRU_NINE:n {return($n)}
]

VSUB_DIGIT [
  [ zero oh ] {return(0)}
  VSUB_DIGIT_ONE_THRU_NINE:n {return($n)}
]

; Single-digit grammars that return string values

VSUB_DIGIT_TWO_THRU_NINE_STRING [
  two {return("2")}
  three {return("3")}
  four {return("4")}
  five {return("5")}
  six {return("6")}
  seven {return("7")}
  eight {return("8")}
  nine {return("9")}
]

VSUB_DIGIT_ONE_THRU_NINE_STRING [
  one {return("1")}
  VSUB_DIGIT_TWO_THRU_NINE_STRING:n {return($n)}
]

VSUB_DIGIT_STRING [
  [ zero oh ] {return("0")}
  VSUB_DIGIT_ONE_THRU_NINE_STRING:n {return($n)}
]

VSUB_TEEN_STRING [
  eleven {return("11")}
  twelve {return("12")}
  thirteen {return("13")}
  fourteen {return("14")}
  fifteen {return("15")}
  sixteen {return("16")}
  seventeen {return("17")}
  eighteen {return("18")}
  nineteen {return("19")}
]

VSUB_DECADE_STRING [
  twenty {return("2")}
  thirty {return("3")}
  forty {return("4")}
  fifty {return("5")}
  sixty {return("6")}
  seventy {return("7")}
  eighty {return("8")}
  ninety {return("9")}
]

VSUB_TEEN [
  eleven {return(11)}
  twelve {return(12)}
  thirteen {return(13)}
  fourteen {return(14)}
  fifteen {return(15)}
  sixteen {return(16)}
  seventeen {return(17)}
  eighteen {return(18)}
  nineteen {return(19)}
]

VSUB_DECADE [
  twenty {return(20)}
  thirty {return(30)}
  forty {return(40)}
  fifty {return(50)}
  sixty {return(60)}
  seventy {return(70)}
  eighty {return(80)}
  ninety {return(90)}
]